DominoArea.org [Archive]

bonjour,

je cherche à récupérer les information d'héritage de template, des bases courriers dans l'onglet Design.
Il ne s'agit pas des propriétés Templatename ou DesigntemplateNale fournies en standard par la classe Base de doc, mais plutôt la version du modèle, que l'on voit en dessous du champs "Nom du modèle" ou "repose sur....", car parfois, j'ai des db, dont cette valeur est vide...

merci

salut

essais ça pour voir

Code : Tout sélectionner

Public Function DBTemplateInfo(wDB As NotesDatabase)
   Dim lstInfo List As String
   Dim DBCible As NotesDatabase
   Dim NotesCollection As NotesNoteCollection
   Dim Doc As NotesDocument
   
   On Error GoTo CatchError
   
   lstInfo("TEMPLATENAME") = ""
   lstInfo("DESIGNTEMPLATENAME") = ""
   lstInfo("TEMPLATEBUILD") = ""
   lstInfo("TEMPLATEBUILDDATE") = ""
   lstInfo("TEMPLATEBUILDNAME") = ""
   
   If Session Is Nothing Then
      Set Session = New NotesSession
   End If   
   
   If wDB Is Nothing Then
      Set DBCible = Session.CurrentDatabase
   Else         
      Set DBCible = wDB
   End If
   
   lstInfo("TEMPLATENAME") = DBCible.TemplateName
   lstInfo("DESIGNTEMPLATENAME") = DBCible.DesignTemplateName
   
   Set NotesCollection = DBCible.CreateNoteCollection(False)
   NotesCollection.SelectSharedFields = True
   NotesCollection.SelectionFormula = {$TITLE = "$TemplateBuild"}
   Call NotesCollection.BuildCollection
   
   If notesCollection.Count > 0 Then
      Set Doc = DocSearchByUNID(CStr(NotesCollection.GetFirstNoteId),DBCible,"","")
      
      If Not Doc Is Nothing Then
         lstInfo("TEMPLATEBUILD") = Trim(CStr(Doc.GetItemValue("$TemplateBuild")(0)))
         lstInfo("TEMPLATEBUILDDATE") = Trim(CStr(Doc.GetItemValue("$TemplateBuildDate")(0)))
         lstInfo("TEMPLATEBUILDNAME") = Trim(CStr(Doc.GetItemValue("$TemplateBuildName")(0)))
         lstInfo("TEMPLATEBUILDTOOL") = Trim(CStr(Doc.Getitemvalue("TemplateBuildTool")(0)))
      End If
      Set Doc = Nothing
   End If
   
   Set NotesCollection = Nothing
   Set DBCible = Nothing
   
   DBTemplateInfo = lstInfo
   Erase lstInfo
   
   Exit Function
CatchError:
   MsgBox "("+Cstr(GetThreadInfo (1))+" Call by "+Cstr(GetThreadInfo(10))+")"+Chr(10)+"Error " + CStr(Err) + " : "+Chr(10) + CStr(Error)+". "+Chr(10)+"Line # "+Cstr(Erl),16," ERROR !"
   DBTemplateInfo = null
   Erase lstInfo
   Exit Function
End Function

tout à fait intéressant
merci Michael !

nickel, ça marche !