DominoArea.org [Archive]

Bonjour,

J'ai un soucis avec l'ajout d'un lien vers le document. J'utilise le code ci dessous pour envoyer une notification. Il envoi le text mais il n'ya pas le lien vers le document. et je n'rrive pas à trouver d'ou vien le problème.

Dim docmail As NotesDocument
Dim rtitem As NotesRichTextItem
Set doc = uidoc.Document
Set docmail = New NotesDocument( db )
Set rtitem = New NotesRichTextItem ( docmail, "body" )
docmail.form = "Memo"
docmail.SendTo = doc.GroupeListe

docmail.subject = "Le ticket a été affecté à votre groupe "
Call rtitem.AppendText ( "Bonjour," )
Call rtitem.AddNewLine( 2 )
Call rtitem.AppendText ( "Veulliez trouver ci-dessous le lien vers le ticket < " &uidoc.FieldGetText("SuiviNumero")
Call rtitem.AddNewLine( 2 )
Call rtitem.AppendText ( "Merci de l'affecter à une personne de votre groupe." )
Call rtitem.AddNewLine( 1 )
Call rtitem.AppendText ( "Lien vers l'incident : ----------> " )
Call rtitem.AppendDocLink ( doc, "Document" )

Bonjour,

Que représente Set doc = uidoc.document ?

Je pense qu'il te manque ceci :

Dim ws as New NotesUIWorksapce
Dim uidoc as notesUIdocument
set uidoc = ws.currentdocument

Bonjour,
Si j'ai cette partie dans mon code c'est juste que je ne l'ai pas copié pour que ça ne fasse pas trop long ,car avant d'envoyer le mail je fais d'autre traitement.

Je n'arrive pas à comprendre pourquoi il n'ajoute pas le lien.

Dim doc As NotesDocument
Dim session As NotesSession
Dim db As NotesDatabase
Dim workspace As New NotesUIWorkspace
Dim uidoc As NotesUIDocument
Dim answer As Integer
Dim groupe As String

Set session = New NotesSession
Set db = session.currentdatabase
Set uidoc = workspace.CurrentDocument
Set doc = uidoc.Document

Ton document uidoc en cours est-il enregistré dans la base.

Un code simple mais efficace, avec gestion de l'erreur et contrôle de l'exécution

'//********************************************************************************* Bouton
Sub Click(Source As Button)
Dim ws As New notesuiworkspace
Dim note As NotesDocument
Dim db As NotesDatabase

Set db = ws.CurrentDatabase
Set note = ws.CurrentDocument.Document

If SendMemoNotificaiton(note,"Frederic Fernandez","Le message était .....") = True Then
Msgbox "message envoyé",64, db.Title
End If
End Sub
'//**********************************************************************************Fonction

Function SendMemoNotificaiton(Note As NotesDocument,strDestinataire As String,strMessage as string)As Boolean

On Error Goto Erreur_Fin

SendMemoNotificaiton = False

Dim session As New NotesSession
Dim db As NotesDatabase
Dim newDoc As NotesDocument
Dim doc As NotesDocument

Dim rtitem As NotesRichTextItem
Dim rtStyle As NotesRichTextStyle
Dim rtStyleParagraphe As NotesRichTextParagraphStyle
Dim nNameDestinataire As notesName

Set nNameDestinataire = session.CreateName(strDestinataire)
Set db = session.CurrentDatabase
Set newDoc = db.CreateDocument
Set rtitem = New NotesRichTextItem( newDoc, "Body" )
Set rtStyle = session.CreateRichTextStyle
Set rtStyleParagraphe = session.CreateRichTextParagraphStyle

With rtitem
Call .AppendText("Bonjour,")
Call .AddNewLine( 2 )
Call .AddTab( 1 )
Call .AppendText(strMessage)
Call .AddNewLine( 1 )
Call .AddTab( 1 )
Call .AppendText("Cordialement")
Call .AddNewLine( 2 )
With rtStyle
.NotesColor = COLOR_BLACK
.NotesFont = FONT_HELV
.FontSize=8
.Underline=False
.Bold= True
End With
Call .AppendStyle(rtStyle)
Call .AppendText("Cliquer ici pour ouvrir le document de réservation -->")
Call .AppendDocLink( note, db.Title )
End With
newDoc.form ="Memo"
newDoc.Subject ="Mon sujet"
newDoc.SendTo = nNameDestinataire.abbreviated
Call newDoc.Send( False )

SendMemoNotificaiton = True
Exit Function

Erreur_Fin:
Msgbox Error, 16, Err
SendMemoNotificaiton = False
Exit Function
End Function

salut

petite information. les doclink fonctionnent si et seulement si une vue par défaut est déclarer dans la base ou se situe le document linké

Merci beaucoup pour vos réponse.

Effectivement c'est une vue par défaut qui n'était pas déclarée.

Merci et bon week end