Export avec feuille XSL

[billbock]

Code : Tout sélectionner

%INCLUDE "lsxbeerr.lss"

On Error lsERR_NOTES_XSLT_INPUT_OBJECT Goto err_IN
   On Error lsERR_NOTES_XSLT_OUTPUT_OBJECT Goto err_OUT
   On Error lsERR_NOTES_XSLT_STYLESHEET_OBJECT Goto err_SS
   
   Dim session As New NotesSession
   Dim db As Notesdatabase
   Set db = session.currentdatabase
   
   
   filename$ = "dxlhelloworld_data"
   pathname$ = "C:\dxl\"
   
   Dim stream As NotesStream    ' dxl file
   Set stream=session.CreateStream
   
   Dim XSL_ss As NotesStream    ' style sheet
   Set XSL_ss=session.CreateStream
   If Not XSL_ss.Open(pathname$ +  filename$ +".xsl") Then
      Messagebox "Cannot open " + filename$,, "XSL file error"
      Exit Sub
   End If
   
   Dim XML_out As NotesStream    ' output file
   Set XML_out=session.CreateStream
   If Not XML_out.Open(pathname$ + filename$ + ".xml") Then
      Messagebox "Cannot create " + filename$,, "TXT file error"
      Exit Sub
   End If
   XML_out.Truncate
   
  'Build a NoteCollection to limit the export file to documents
   Dim nc As NotesNoteCollection
   Set nc = db.CreateNoteCollection(False)
   nc.SelectDocuments=True
   Call nc.BuildCollection
   
  'Create the Exporter   
   Dim exporter As NotesDXLExporter
   Set exporter = session.CreateDXLExporter(nc, stream)
   
  'Create the Transformer
   Dim transformer As NotesXSLTransformer
   Set transformer=session.CreateXSLTransformer(exporter, XSL_ss, XML_out)
   
   Call exporter.Process
   Exit Sub
   
err_IN:
   Messagebox "XSL Input error", , "XSLTransformer Process"
   Exit Sub
err_OUT:
   Messagebox "XSL Output error", , "XSLTransformer Process"
   Exit Sub
err_SS:
   Messagebox "Style Sheet error", , "XSLTransformer Process"
   Exit Sub