DominoArea.org [Archive]

Bonjour

nous avons tous un jour ce type de problématique : comment dans un mail existant donc non MIME insérer un lien HTML

voici une solution :

il faut une form ici appelé "WEBLinkForm" qui contient le champs "Body" et sa mise en page

voici le code

Code : Tout sélectionner

Sub AppendWebLink (Body As NotesRichTextItem, doc As NotesDocument, comment As string)
   Dim s As New NotesSession
   Dim db As NotesDatabase
   Dim docTemp As NotesDocument
   Dim bodyTemp As NotesMIMEEntity
   Dim serveur As NotesName
   Dim stream As NotesStream
   On Error GoTo Herr
   
    ' creation d'un body temporaire de type Mime
   s.ConvertMIME = False ' Do not convert MIME to rich text
   Set db = s.currentDatabase
   Set docTemp = db.CreateDocument
   docTemp.form = "WEBLinkForm"
   
   Set bodyTemp = docTemp.CreateMIMEEntity
   
    ' ajout du lien dans ce body
   Set stream = s.CreateStream
   Set serveur = New NotesName (doc.Parentdatabase.Server)
   stream.writeText ("<a href='http://"+serveur.Common+":8001/"+db.Filepath+"/Home.html?OpenPage&debug=true&idOpenDocument="+doc.Universalid+"'>"+comment+"</a>")
   Call bodyTemp.SetContentFromText(stream, "text/html", ENC_IDENTITY_8BIT) 
   
   Call docTemp.save (True, false)
    ' ajout de ce body dans le body principale
   Call docTemp.Rendertortitem(body)
   
   Call docTemp.remove(True)
   s.ConvertMIME = True ' Restore conversion
   
exitSub:
   Exit sub
Herr:
   MsgBox "error in AppendWebLink " + Error + " ligne " + CStr (Erl)
   Resume exitSub
End Sub

L'idée est de crée un mail temporaire de type Mime, d'y ajouter le HTML
puis de l'ajouter au body, on peu bien sur l'adapter pour insérer tout les objet HTML que l'on souhaite.

Voila en espérant que cela serve à quelqu'un